Template testing

[dkrupicka]

Hello,

is there a way how to test the code embedded in html templates, i.e. just pass the needed variables and test the result?

Best regards
David

[Akron]

Yes - and it's fairly simple. You can directly test templates using the Mojo::Template API like this:

#!/usr/bin/env perl
use Mojo::Template;
use Test::More;

my $mt = Mojo::Template->new;
my $template_rendering = $mt->vars(1)->render(<<'TEMP', {works => 'Also fun'});
<p><%= uc($works) %></p>
TEMP

is($template_rendering,"<p>ALSO FUN</p>\n");

done_testing;

So simply render the template with the passed values and check the result.

You can also check the code on a higher level (e.g. when not using Mojo::Template as your template engine) by using Test::Mojo like this:

#!/usr/bin/env perl
use Mojolicious::Lite;
use Test::Mojo;
use Test::More;

helper print_uc => sub {
  my ($c, $str) = @_;
  return uc($str);
};

get '/' => 'fun';

get '/fine' => sub {
  my $c = shift;
  $c->stash(works => 'FUN');
  $c->render('fun');
};

# Test the embedded code
my $t = Test::Mojo->new;

$t->get_ok('/')
  ->status_is(500)
  ;

$t->get_ok('/fine')
  ->status_is(200)
  ->text_is('p', 'FUN')
  ;

done_testing;

__DATA__
@@fun.html.ep
<p><%= print_uc($works) %></p>

[s1037989]

To traverse the HTML, use Mojo::DOM -- there's nothing better!

[dkrupicka]

Thanks a lot, I will try!

[dkrupicka]

Although, citing the docu It will even try to interpret broken HTML and XML, so you should not use it for validation. ...
So maybe I could use e.g. HTML::Lint at first.

[ernstki]

my $template_rendering = $mt->vars(1)->render(<<'TEMP', {works => 'Also fun'});

@Akron Do you personally have any intution for why ->vars(1) should be required?

It's always the same as the number of keys passed in, at least in this simple example. So I just don't understand why I'd get

Global symbol "$works" requires explicit package name

if I forgot the ->vars(1) here.

[ernstki]

Oh, ha, it's somewhat clearer now that I see this in the docs

$mt      = $mt->vars($bool);

So it's not a number of variables, it's a true/false value. Total misunderstanding on my part. *facepalm*

I'm guessing this is because Perl collapses sub-lists, and there'd be no way to tell whether a list or a hash of values were passed in otherwise.